00056 98/05/12 11:18

（発言者削除）

投稿者：よこしま

00057 98/05/12 11:18

（発言者削除）

投稿者：よこしま

00058 98/05/12 11:21

NIF.HSCで発言に署名を挿入

投稿者：よこしま

コメントを投稿する

NIF.HSC(v4.32に付属)で自動発言する際に
発言の末尾に自動的に署名を入れるための改造例です.
この次の発言とペアになっています.

改造の仕方

(1) 次の発言(タイトルはSgnUp.hsc)を丸ごとコピーして
SgnUp.hsc という名前で保存し, 秀termのスクリプト
ホルダーにコピーします.

(2) NIF.HSCの1552行目付近に

writefile "nifhsc.$$$", "/POST"
closefile "nifhsc.$$$"
upload "nifhsc.$$$", none
chdir upload
delfile "nifhsc.$$$"
restoredir
if( ##HideNet == 0 )

というのがあるので, これを以下で置き換えます.

---------------------------
; writefile "nifhsc.$$$", "/POST" ;<-コメントにする
closefile "nifhsc.$$$"
upload "nifhsc.$$$", none
chdir upload
delfile "nifhsc.$$$"
restoredir

;追加ここから
call SgnUp.hsc
readbuffer 0, #buffer
if(#buffer != "")
send "^M"
wait "^M"
endif
send "/POST^M"
;追加ここまで

if( ##HideNet == 0 )
-----------------------------

これで改造は終了です.

使い方

(1)MySgn.txtというファイルをアップロードホルダーに
作り自由に署名文を書いて下さい.

(2)シグニチャーには以下の埋め込みコマンドが使えます.

%date ・・・今日の日付(曜日なし) %now ・・・現在時刻
%week ・・・今日の曜日 %Week ・・・今日の曜日(英字)
%today ・・・今日の日付(曜日付き)
%hh ・・・現在時刻の時 %h2 ・・・現在時刻の時(12時間表記)
%mm ・・・現在時刻の分 %ss ・・・現在時刻の秒
%ampm ・・・午前なら am, 午後なら pm

以上

よこしま

00059 98/05/12 11:21

SgnUp.hsc

投稿者：よこしま

コメントを投稿する

;発言ファイルをアップロードするときに
;一緒にシグニチャーを追加送信するためのスクリプトです.
;自動発言ルーチンから呼び出すことを前提にしています.
;ご使用中のスクリプトファイルの最後に貼り付けて下さい.
;
;
;使い方(1)
;
;アップロードホルダーに MySgn.txt というのを作ってそれにシグニチャーを
;書いておく場合
; call SendSgn2
;とする.
;
;使い方(2)
;
;任意の場所に任意の名前のファイルを作成しそれにシグニチャーを
;書いておく場合
; call SendSgn "ファイル名"
;とする. (ファイル名はフルパスでかく)
;
;このスクリプトを別ファイル(たとえば SgnUp.hsc)にする場合は,
;上でそれぞれ
; call SgnUp.hsc:SendSgn2
;
; call SgnUp.hsc:SendSgn "ファイル名"
;
;とする.
;
;シグニチャーには以下の埋め込みコマンドが使用できます.
;
; %date ・・・今日の日付(曜日なし) %now ・・・現在時刻
; %week ・・・今日の曜日 %Week ・・・今日の曜日(英字)
; %today ・・・今日の日付(曜日付き)
; %hh ・・・現在時刻の時 %h2 ・・・現在時刻の時(12時間表記)
; %mm ・・・現在時刻の分 %ss ・・・現在時刻の秒
; %ampm ・・・午前なら am, 午後なら pm
;
;
;
;ここから本文

SendSgn2:
openreg "CURRENTUSER", "Software\Hidemaruo\HideTerm95\Config"
getreg "UploadPath", #uppath
closereg

#1 == #uppath + "\MySgn.txt"
#exist == existfile(#1)
if(#exist == "")
return
endif

SendSgn:
#sgnfile == #1
call GetTimeInfo

openfile #sgnfile
readfile #sgnfile, #upline

beginloop
call LineChange #upline
sendwrap #return + "^M"

readfile #sgnfile, #upline
if(no)
closefile #sgnfile
breakloop
endif
endloop

return

GetTimeInfo:
getdate #date
getweek #week
switch #week
case "日"
#week2 == "Sun"
case "月"
#week2 == "Mon"
case "火"
#week2 == "Tue"
case "水"
#week2 == "Wed"
case "木"
#week2 == "Thu"
case "金"
#week2 == "Fri"
case "土"
#week2 == "Sat"
endswitch

gettime #time

##time == value(part(#time,0,2))

if(##time > 11)
@ampm == "pm"
else
@ampm == "am"
endif

if(##time>12)
##time == ##time - 12
endif

if(##time <10)
@h2 == "0" + ##time
else
@h2 == ##time
endif

if(##time = 0)
@h2 == "12"
endif

@today = part(#date,0,2) + "/" + part(#date,2,2) \
+ "/" + part(#date,4,2)+ "(" + #week + ")"
@date = part(#date,0,2) + "/" + part(#date,2,2) \
+ "/" + part(#date,4,2)
@week = #week
@week2 = #week2
@now = part(#time,0,2) + ":" + part(#time,2,2)
@mm == part(#time,2,2)
@ss == part(#time, 4,2)
@hh == part(#time, 0, 2)
return

LineChange:
#line == #1

if(search(#line, "%today"))
#b == drop(#line, "%today")
#c == part(search(#line, "%today"), 6,255)
#line = #b + @today + #c
endif

if(search(#line, "%date"))
#b == drop(#line, "%date")
#c == part(search(#line, "%date"), 5,255)
#line = #b + @date + #c
endif

if(search(#line, "%week"))
#b == drop(#line, "%week")
#c == part(search(#line, "%week"), 5,255)
#line = #b + @week + #c
endif

if(search(#line, "%Week"))
#b == drop(#line, "%Week")
#c == part(search(#line, "%Week"), 5,255)
#line = #b + @week2 + #c
endif

if(search(#line, "%now"))
#b == drop(#line, "%now")
#c == part(search(#line, "%now"), 4,255)
#line = #b + @now + #c
endif

if(search(#line, "%hh"))
#b == drop(#line, "%hh")
#c == part(search(#line, "%hh"), 3,255)
#line = #b + @hh + #c
endif

if(search(#line, "%mm"))
#b == drop(#line, "%mm")
#c == part(search(#line, "%mm"), 3,255)
#line = #b + @mm + #c
endif

if(search(#line, "%ss"))
#b == drop(#line, "%ss")
#c == part(search(#line, "%ss"), 3,255)
#line = #b + @ss + #c
endif

if(search(#line, "%h2"))
#b == drop(#line, "%h2")
#c == part(search(#line, "%h2"), 3,255)
#line = #b + @h2 + #c
endif

if(search(#line, "%ampm"))
#b == drop(#line, "%ampm")
#c == part(search(#line, "%ampm"), 5,255)
#line = #b + @ampm + #c
endif

return #line

;本文ここまで

00060 98/05/12 17:28

（発言者削除）

投稿者：ま神５１号

00061 98/05/12 23:11

（発言者削除）

投稿者：ま神５１号

00062 98/05/12 23:27

RE:00060 （発言者削除）

投稿者：ま神５１号

コメントを投稿する

60番は書く場所を間違えて、61番は勘違いです。m(_ _)m

新規に投稿する